ReadComponent方法主要是調用ReadComponent方法從Reader對象的流中讀取一連串相關聯的部件，并分解相互引用關系。

　　procedure TReader.ReadComponents(AOwner, AParent: TComponent;

　　Proc: TReadComponentsProc);

　　var

　　Component: TComponent;

　　begin

　　Root := AOwner;

　　Owner := AOwner;

　　Parent := AParent;

　　BeginReferences;

　　try

　　while not EndOfList do

　　begin

　　ReadSignature;

　　Component := ReadComponent(nil);

　　Proc(Component);

　　end;

　　FixupReferences;

　　finally

　　EndReferences;

　　end;

　　end;

　　ReadComponents首先用AOwner和AParent參數給Root,Owner和Parent賦值，用于重建各部件的相互引用。然后用一個While循環讀取部件并用由Proc傳入的方法進行處理。在重建引用關系時，用了BeginReferences、FixUpReferences和EndReferences嵌套模式。

　　ReadRootComponent方法從Reader對象的流中將部件及其擁有的部件全部讀出。如果Component參數為nil，則創建一個相同類型的部件，最后返回該部件：

　　function TReader.ReadRootComponent(Root: TComponent): TComponent;

　　function FindUniqueName(const Name: string): string;

　　begin

　　…

　　end;

　　var

　　I: Integer;

　　Flags: TFilerFlags;

　　begin

　　ReadSignature;

　　Result := nil;

　　try

　　ReadPrefix(Flags, I);

　　if Root = nil then

　　begin

　　Result := TComponentClass(FindClass(ReadStr)).Create(nil);

　　Result.Name := ReadStr;

　　end else

　　begin

　　Result := Root;

　　ReadStr; { Ignore class name }

　　if csDesigning in Result.ComponentState then

　　ReadStr else

　　Result.Name := FindUniqueName(ReadStr);

　　end;

　　FRoot := Result;

　　if GlobalLoaded <> nil then

　　FLoaded := GlobalLoaded else

　　FLoaded := TList.Create;

　　try

　　FLoaded.Add(FRoot);

　　FOwner := FRoot;

　　Include(FRoot.FComponentState, csLoading);

　　Include(FRoot.FComponentState, csReading);

　　FRoot.ReadState(Self);

　　Exclude(FRoot.FComponentState, csReading);

　　if GlobalLoaded = nil then

　　for I := 0 to FLoaded.Count - 1 do TComponent(FLoaded[I]).Loaded;

　　finally

　　if GlobalLoaded = nil then FLoaded.Free;

　　FLoaded := nil;

　　end;

　　GlobalFixupReferences;

　　except

　　RemoveFixupReferences(Root, '');

　　if Root = nil then Result.Free;

　　raise;

　　end;

　　end;

　　ReadRootComponent首先調用ReadSignature讀取Filer對象標簽。然后在try…except循環中執行讀取任務。如果Root參數為nil，則用ReadStr讀出的類名創建新部件，并以流中讀出部件的Name屬性;否則，忽略類名，并判斷Name屬性的唯一性。最后用Root的ReadState方法讀取屬性和其擁有的擁有并處理引用關系。

　　7. SetName方法和OnSetName事件

　　因為在OnSetName事件中，Name參數是var型的，所以可以用OnSetName事件處理過程修改所讀部件的名字。而OnSetName事件處理過程是在SetName方法中實現的。

　　procedure TReader.SetName(Component: TComponent; var Name: string);

　　begin

　　if Assigned(FOnSetName) then FOnSetName(Self, Component, Name);

　　Component.Name := Name;

　　end;

　　SetName方法和OnSetName事件在動態DFM文件的編程中有很重要的作用。

　　8. TReader的錯誤處理

　　TReader的錯誤處理是由Error方法和OnError事件的配合使用完成的。OnError 事件處理過程的Handled參數是var型的布爾變量，通過將Handled設為True或False可影響TReader 的錯誤處理。OnError事件處理過程是在Error方法中調用的。

　　function TReader.Error(const Message: string): Boolean;

　　begin

　　Result := False;

　　if Assigned(FOnError) then FOnError(Self, Message, Result);

　　end;

　　9. FindMethod和OnFindMethod事件

　　有時，在程序運行期間，給部件的方法指針(主要是事件處理過程)動態賦值是很有用的，這樣就能動態地改變部件響應事件的方式。在流中讀取部件捍做到一點就要利用OnFindMehtod事件。OnFIndMethod事件是在FindMethod方法中被調用的。

　　function TReader.FindMethod(Root: TComponent;

　　const MethodName: string): Pointer;

　　var

　　Error: Boolean;

　　begin

　　Result := Root.MethodAddress(MethodName);

　　Error := Result = nil;

　　if Assigned(FOnFindMethod) then FOnFindMethod(Self, MethodName, Result,

　　Error);

　　if Error then PropValueError;

　　end;

　　OnFindMethod 方法除了可以給部件的MethodName所指定的方法指針動態賦值外，還可修改Error參數來決定是否處理Missing Method錯誤。方法中調用的MehtodAddress 方法定義在TObject中，它是個很有用的方法，它可以得到對象中定義的public方法的地址。FindMethod方法和OnFindMethod事件在動態DFM的編程中有很重要的作用。

　　20.3 Delphi對象式數據管理應用實例

　　Delphi 2.0無論是其可視化設計工具，還是可視化部件類庫(VCL)，都處處滲透了對象存儲技術，本節將從Delphi可視化設計內部機制、VCL中的數據存儲、BLOB數據操作和動態生成部件的存儲幾方面介紹對象存儲功能的實例應用。

　　20.3.1 Delphi 動態DFM文件及部件的存取在超媒體系統中的應用

　　Delphi的可視化設計工具是同其部件類庫緊密結合在一起的。

　　每個部件只有通過一段注冊程序并通過Delphi的Install Component功能，才能出現在Component Palette上;部件的屬性才有可能出現在Object Inspector窗口中;部件的屬性編輯器才能被Delphi環境使用。因為這種渾然天成的關系，DFM文件存取必然得到VCL在程序上的支持。

　　DFM文件的部件存取是Delphi可視化設計環境中文件存取的中心問題。因為Delphi可視化設計的核心是窗體的設計。每個窗體對應一個庫單元，是應用程序的模塊，窗體在磁盤上的存儲就是DFM文件。

　　DFM文件結構我們前面介紹過了。它實際上是存儲窗體及其擁有的所有部件的屬性。這種擁有關系是遞歸的。問題在于如何將這些屬性數據與程序中的變量(屬性)代碼聯系起來。

　　在Delphi中處理這種聯系的過程分為兩種情況：設計時和運行時。

　　在設計時，建立聯系表現為讀取DFM 文件，建立DFM文件中的部件及其屬性與可視化設計工具(Object Inspector、窗體設計窗口和代碼編輯器)的聯系，也就是說讓這些部件及其屬性能出現在這些窗口中，并與代碼中的屬性定義聯系起來;分解聯系表現為存儲DFM文件，將窗體窗口中的部件及其屬性寫入DFM文件。

　　在運行時，主要是建立聯系的過程，即讀取DFM文件。這時，DFM文件不是作為獨立的磁盤文件，而是以應用程序資源中的RCDATA類型的二進制數據存在。建立聯系的過程表現為將資源中的部件及其屬性與應用程序中的對象及其數據域聯系起來。其過程為：根據DFM中的部件類名創建對象，再將用DFM中的部件屬性值給程序中的部件屬性賦值。當然要完成這一過程，還必須在代碼中有相應的窗體定義，因為方法等代碼是不存入部件的。

　　VCL對讀取DFM文件在代碼上的支持是通過Stream對象和Filer對象達到的。在20. 1和20.1節中，我們可以看到Stream對象和Filer對象中有大量的用于存取部件及其屬性的方法，尤其在TReader對象中，還有關于錯誤處理和動態的方法賦值的方法。下面我們就通過程序實例介紹存取DFM文件方法、步驟和注意事項。

　　20.3.1.1寫DFM文件的過程：WriteComponentResFie

　　該過程帶有兩個參數FileName和Instance。FileName參數指定要寫入的DFM文件名，Instance參數是TComponent類型的，它指定要寫入的部件名，一般是TForm對象的子類。該過程將Instance部件和其擁有的所有部件寫入DFM文件。

　　這個過程的意義在于，可以在程序運行過程中產生Delphi的窗體部件和在窗體中插入部件，并由該函數將窗體寫入DFM文件，支持了動態DFM文件的重用性。

　　該過程的程序是這樣的：

　　procedure WriteComponentResFile(const FileName: string; Instance: TComponent);

　　var

　　Stream: TStream;

　　begin

　　Stream := TFileStream.Create(FileName, fmCreate);

　　try

　　Stream.WriteComponentRes(Instance.ClassName, Instance);

　　finally

　　Stream.Free;

　　end;

　　end;

　　函數中，用FileStream創建文件，用Stream對象的WriteComponetRes方法將Instance寫入流中。

　　20.3.1.2 讀DFM文件的函數：ReadComponentResFile

　　ReadComponentResFile函數帶有兩個參數FileName和Instance。FileName參數指定要讀DFM文件名，Instance參數指定從DFM文件中要讀的部件。該函數從DFM文件中將Instance和它擁有的所有部件，并返回該部件。

　　這個函數的意義在于，配合WriteComponentResFile過程的使用支持DFM文件的重用性。

　　該函數的程序是這樣的：

　　function ReadComponentResFile(const FileName: string; Instance: TComponent):

　　TComponent;

　　var

　　Stream: TStream;

　　begin

　　Stream := TFileStream.Create(FileName, fmOpenRead);

　　try

　　Result := Stream.ReadComponentRes(Instance);

　　finally

　　Stream.Free;

　　end;

　　end;

　　程序中使用FileStream對象打開由FileName指定的DFM文件，然后用Stream對象的ReadComponentRes方法讀出Instance，并將讀的結果作為函數的返回值。

　　20.3.1.3 讀取Delphi應用程序資源中的部件

　　函數InternalReadComponentRes可以讀取Delphi應用程序資源中的部件。Delphi 的DFM文件在程序經過編譯鏈接后被嵌入應用程序的資源中，而且格式發生了改變，即少了資源文件頭。

　　在第一節中曾經介紹過TResourceStream對象，該對象是操作資源媒介上的數據的。函數InternalReadComponentRes用了TResourceStream。程序是這樣的：

　　function InternalReadComponentRes(const ResName: string;

　　var Instance: TComponent): Boolean;

　　var

　　HRsrc: THandle;

　　begin { 避免“EResNotFound”異常事件的出現 }

　　HRsrc := FindResource(HInstance, PChar(ResName), RT_RCDATA);

　　Result := HRsrc <> 0;

　　if not Result then Exit;

　　FreeResource(HRsrc);

　　with TResourceStream.Create(HInstance, ResName, RT_RCDATA) do

　　try

　　Instance := ReadComponent(Instance);

　　finally

　　Free;

　　end;

　　Result := True;

　　end;

　　HInstance是一個Delphi VCL定義的全局變量，代表當前應用程序的句柄。函數用了資源訪問API函數FindResource來測定是否存在ResName所描述資源。因為在TResourceStream的創建過程還有FindResource等操作，所以函數中調用了FreeResource。最后函數調用了Stream對象的ReadComponent方法讀出部件。因為函數的Instance是var類型的參數，所以可以訪問Instance，得到讀出的部件。

　　20.3.1.4 DFM文件與標準文本文件(TXT文件)的相互轉換

　　在Delphi可視化設計環境中，允許程序員在代碼編輯器中以文本的方式瀏覽和修改DFM文件內容。當用File/Open命令直接打開DFM文件或者選擇窗體設計窗口的彈出式菜單上的View as Text命令時，就會在編輯器中出現文本形式的信息。我們姑且將這種文本形式稱之為窗體設計腳本。Delphi提供的這種腳本編輯功能是對Delphi可視化設計的一大補充。當然這個腳本編輯能力是有限制的，比方說不能在腳本任意地添加和刪除部件，因為代碼和DFM腳本是緊密相連的，任意添加和修改會導致不一致性。然而在動態生成的DFM文件中，就不存在這一限制，后面會介紹DFM動態生成技術的應用。

　　實際上，DFM文件內容是二進制數據，它的腳本是經過Delphi開發環境自動轉化的，而且Delphi VCL中的Classes庫單元中提供了在二進制流中的文件DFM和它的腳本之相互轉化的過程。它們是ObjectBinaryToText和ObjectTextBinary、ObjectResourceToText和ObjectTextToResource。

　　ObjectBinaryToText過程將二進制流中存儲的部件轉化為基于文本的表現形式，這樣就可以用文本處理函數進行處理，還可以用文本編輯器進行查找和替代操作，最后可以將文本再轉化成二進制流中的部件。

　　ObjectBinaryToText過程的主程序是這樣的：

　　procedure ObjectBinaryToText(Input, Output: TStream);

　　var

　　NestingLevel: Integer;

　　SaveSeparator: Char;

　　Reader: TReader;

　　Writer: TWriter;

　　procedure WriteIndent;

　　const

　　Blanks: array[0..1] of Char = ' ';

　　var

　　I: Integer;

　　begin

　　for I := 1 to NestingLevel do Writer.Write(Blanks, SizeOf(Blanks));

　　end;

　　procedure WriteStr(const S: string);

　　begin

　　Writer.Write(S[1], Length(S));

　　end;

　　procedure NewLine;

　　begin

　　WriteStr(#13#10);

　　WriteIndent;

　　end;

　　procedure ConvertHeader;

　　begin

　　…

　　end;

　　procedure ConvertBinary;

　　begin

　　…

　　end;

　　procedure ConvertValue;

　　begin

　　…

　　end;

　　procedure ConvertProperty;

　　begin

　　…

　　end;

　　procedure ConvertObject;

　　begin

　　…

　　end;

　　begin

　　NestingLevel := 0;

　　Reader := TReader.Create(Input, 4096);

　　SaveSeparator := DecimalSeparator;

　　DecimalSeparator := '.';

　　try

　　Writer := TWriter.Create(Output, 4096);

　　try

　　Reader.ReadSignature;

　　ConvertObject;

　　finally

　　Writer.Free;

　　end;

　　finally

　　DecimalSeparator := SaveSeparator;

　　Reader.Free;

　　end;

　　end;

　　過程中調用的ConvertObject過程是個遞歸過程，用于將DFM文件中的每一個部件轉化為文本形式。因為由于部件的擁有關系，所以部件成嵌套結構，采用遞歸是最好的方式：

　　procedure ConvertObject;

　　begin

　　ConvertHeader;

　　Inc(NestingLevel);

　　while not Reader.EndOfList do ConvertProperty;

　　Reader.ReadListEnd;

　　while not Reader.EndOfList do ConvertObject;

　　Reader.ReadListEnd;

　　Dec(NestingLevel);

　　WriteIndent;

　　WriteStr('end'#13#10);

　　end;

　　NestStingLevel變量表示部件的嵌套層次。WriteIndent是寫入每一行起始字符前的空格，ConvertHeader過程是處理部件的繼承標志信息。轉換成的頭信息文本有兩種形式。

　　Inherited TestForm1: TTestForm[2]